Data model
Standardized semantic models built by the community
All data published on the Tourism Flanders Open Data Portal is compliant with the OSLO standard of the Flemish government . The Logies vocabularium and accompanying Logies Basis application profile are most relevant in the context of tourism.
The vocabulary serves as the underlying structure for our published data. It provides a clear and organized framework for understanding the information you encounter. It's not just about data; it's about meaningful relationships and connections between terms allowing you to navigate and interpret the information with simplicity and clarity.
Logies and registrations
The central class in the data model is Logies , representing any construction, facility, space or land that offers tourists accommodation for one or more nights. Each logies record carries a commercial name and a unique identifier. Most details of the logies (location, capacity, contact information, ...) are covered by related entities.
Official recognitions by Tourism Flanders are captured in the Registratie class. A registration holds its own identifier, a status from a controlled vocabulary, a type category as assigned by the responsible organisation, and optional creation and termination dates. Through this registration, you can determine whether an accommodation is currently recognised, suspended or revoked.
Quality labels
The Kwaliteitslabel class records labels granted to an accommodation when it meets specific conditions set by a certifying body. Each label has a name and an issuing organisation.
The following quality labels are available on this portal:
| Label | Organisation |
|---|---|
| Green Key | GoodPlanet Belgium |
| Kampeerlabel | Toerisme Vlaanderen |
| Opgenomen in icoonfietsroutes | Toerisme Vlaanderen |
| Toegankelijkheidslabel A | Toerisme Vlaanderen |
| Toegankelijkheidslabel A+ | Toerisme Vlaanderen |
To retrieve all Logies with an accessibility label via SPARQL:
PREFIX mu: <http://mu.semte.ch/vocabularies/core/>
PREFIX schema: <http://schema.org/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX logies: <https://data.vlaanderen.be/ns/logies#>
SELECT ?uri ?name ?accessibilityLabel
WHERE {
?uri a logies:Logies ;
schema:name ?name ;
logies:heeftKwaliteitslabel ?label .
?label skos:prefLabel ?accessibilityLabel .
VALUES ?accessibilityLabel {
"Toegankelijkheidslabel A"@nl
"Toegankelijkheidslabel A+"@nl
}
}Capacities
Capacity figures are expressed using the KwantitatieveWaarde (quantitative value) structure, which combines a numeric value, a human-readable unit description, and a standardised unit code. Capacities are attached to a Logies covering metrics such as the total number of sleeping places or the number of rooms available.
The following capacities are available as quantitative values on this portal:
- aantal campingplaatsen
- aantal campingplaatsen voor kortverblijf
- aantal campingplaatsen voor lange termijn
- aantal plaatsen voor tenten
- aantal staanplaatsen
- aantal toeristische campingplaatsen
- aantal wandelaarshutten
- aantal wooneenheden
- aantal wooneenheden te huur
- normale capaciteit
Example: retrieve the number of wooneenheden for all logies:
PREFIX mu: <http://mu.semte.ch/vocabularies/core/>
PREFIX schema: <http://schema.org/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX logies: <https://data.vlaanderen.be/ns/logies#>
SELECT ?uri ?name ?value
WHERE {
?uri a logies:Logies ;
schema:name ?name ;
logies:capaciteit ?quantitativeValue .
?quantitativeValue schema:value ?value ;
schema:unitText ?unitText .
VALUES ?unitText {
"aantal wooneenheden"@nl
}
}Rating
Ratings are modelled using the
Beoordeling
class, linked to a Logies via schema:starRating. Each rating carries a schema:ratingValue identifying the awarded category. The following rating values are available on this portal:
- 1 *
- 1 * sup
- 2 *
- 2 * sup
- 3 *
- 3 * sup
- 4 *
- 4 * sup
- 5 *
- 5 * sup
- Basic
- Comfort
- Standard
Example: retrieve all logies with a 4 * rating:
PREFIX mu: <http://mu.semte.ch/vocabularies/core/>
PREFIX schema: <http://schema.org/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX logies: <https://data.vlaanderen.be/ns/logies#>
SELECT ?uri ?name ?value
WHERE {
?uri a logies:Logies ;
schema:name ?name ;
schema:starRating ?rating .
?rating schema:ratingValue ?value .
VALUES ?value {
"4 *"
}
}Codelists
Some property values are drawn from a controlled vocabulary rather than being free-form text. These vocabularies are modelled using skos:ConceptScheme, a named set of concepts, where each individual value is a skos:Concept. Using controlled vocabularies ensures consistent, machine-readable values across all published data.
The following codelists are available on this portal:
To retrieve all codelists via SPARQL:
SELECT * WHERE {
?s a <http://www.w3.org/2004/02/skos/core#ConceptScheme> ;
<http://www.w3.org/2004/02/skos/core#prefLabel> ?label .
FILTER(LANG(?label) = "nl")
}To retrieve all concepts within a specific codelist:
SELECT * WHERE {
?scheme a <http://www.w3.org/2004/02/skos/core#ConceptScheme> .
?concept <http://www.w3.org/2004/02/skos/core#inScheme> ?scheme ;
<http://www.w3.org/2004/02/skos/core#prefLabel> ?label .
FILTER(LANG(?label) = "nl")
VALUES ?scheme {
<http://linked.toerismevlaanderen.be/id/conceptschemes/48c5b233-44bc-49d1-93a7-b5005586baa2>
}
}